https://github.com/Kitware/CMake
Tip revision: 624461526f4707a2406ebbd40245a605b6bd41fa authored by Brad King on 04 April 2023, 18:59:48 UTC
CMake 3.26.3
CMake 3.26.3
Tip revision: 6244615
ctest_exclusions.cmake
set(test_exclusions
# This test hits global resources and can be handled by nightly testing.
# https://gitlab.kitware.com/cmake/cmake/-/merge_requests/4769
"^BundleGeneratorTest$"
)
if (CTEST_CMAKE_GENERATOR MATCHES "Visual Studio")
list(APPEND test_exclusions
# This test takes around 5 minutes with Visual Studio.
# https://gitlab.kitware.com/cmake/cmake/-/issues/20733
"^ExternalProjectUpdate$"
# This test is a dependency of the above and is only required for it.
"^ExternalProjectUpdateSetup$")
endif ()
if ("$ENV{CMAKE_CONFIGURATION}" MATCHES "_asan")
list(APPEND test_exclusions
CTestTest2 # crashes on purpose
BootstrapTest # no need to cover this for asan
)
endif()
if ("$ENV{CMAKE_CONFIGURATION}" MATCHES "_jom")
list(APPEND test_exclusions
# JOM often fails with "Couldn't change working directory to ...".
"^ExternalProject$"
)
endif()
if ("$ENV{CMAKE_CONFIGURATION}" MATCHES "nvhpc_")
list(APPEND test_exclusions
# FIXME(#24187): This test fails with NVHPC as the CUDA host compiler.
"^CudaOnly.SeparateCompilationPTX$"
)
endif()
string(REPLACE ";" "|" test_exclusions "${test_exclusions}")
if (test_exclusions)
set(test_exclusions "(${test_exclusions})")
endif ()