Revision 0b2f18e7aeef86f966bbfccec8d698e05ccc4631 authored by Linus Torvalds on 28 August 2020, 20:17:14 UTC, committed by Linus Torvalds on 28 August 2020, 20:17:14 UTC
Pull ACPI fixes from Rafael Wysocki: "These fix two recent issues in the ACPI memory mappings management code and tighten up error handling in the ACPI driver for AMD SoCs (APD). Specifics: - Avoid redundant rounding to the page size in acpi_os_map_iomem() to address a recently introduced issue with the EFI memory map permission check on ARM64 (Ard Biesheuvel). - Fix acpi_release_memory() to wait until the memory mappings released by it have been really unmapped (Rafael Wysocki). - Make the ACPI driver for AMD SoCs (APD) check the return value of acpi_dev_get_property() to avoid failures in the cases when the device property under inspection is missing (Furquan Shaikh)" * tag 'acpi-5.9-rc3' of git://git.kernel.org/pub/scm/linux/kernel/git/rafael/linux-pm: ACPI: OSL: Prevent acpi_release_memory() from returning too early ACPI: ioremap: avoid redundant rounding to OS page size ACPI: SoC: APD: Check return value of acpi_dev_get_property()
stackdelta
#!/usr/bin/env perl
# SPDX-License-Identifier: GPL-2.0
# Read two files produced by the stackusage script, and show the
# delta between them.
#
# Currently, only shows changes for functions listed in both files. We
# could add an option to show also functions which have vanished or
# appeared (which would often be due to gcc making other inlining
# decisions).
#
# Another possible option would be a minimum absolute value for the
# delta.
#
# A third possibility is for sorting by delta, but that can be
# achieved by piping to sort -k5,5g.
sub read_stack_usage_file {
my %su;
my $f = shift;
open(my $fh, '<', $f)
or die "cannot open $f: $!";
while (<$fh>) {
chomp;
my ($file, $func, $size, $type) = split;
# Old versions of gcc (at least 4.7) have an annoying quirk in
# that a (static) function whose name has been changed into
# for example ext4_find_unwritten_pgoff.isra.11 will show up
# in the .su file with a name of just "11". Since such a
# numeric suffix is likely to change across different
# commits/compilers/.configs or whatever else we're trying to
# tweak, we can't really track those functions, so we just
# silently skip them.
#
# Newer gcc (at least 5.0) report the full name, so again,
# since the suffix is likely to change, we strip it.
next if $func =~ m/^[0-9]+$/;
$func =~ s/\..*$//;
# Line numbers are likely to change; strip those.
$file =~ s/:[0-9]+$//;
$su{"${file}\t${func}"} = {size => $size, type => $type};
}
close($fh);
return \%su;
}
@ARGV == 2
or die "usage: $0 <old> <new>";
my $old = read_stack_usage_file($ARGV[0]);
my $new = read_stack_usage_file($ARGV[1]);
my @common = sort grep {exists $new->{$_}} keys %$old;
for (@common) {
my $x = $old->{$_}{size};
my $y = $new->{$_}{size};
my $delta = $y - $x;
if ($delta) {
printf "%s\t%d\t%d\t%+d\n", $_, $x, $y, $delta;
}
}
![swh spinner](/static/img/swh-spinner.gif)
Computing file changes ...