Revision 322c73366a9198d5bd6be08e91b729c775761821 authored by Diane Gallois-Wong on 31 August 2022, 15:57:02 UTC, committed by Marge Bot on 06 September 2022, 08:21:04 UTC
Notably, remove plugin tests on 1M, since the plugin is no longer responsible for enforcing 1M. Similar tests on 1M already exist in tezt, and will be extended in the next commit to cover all the cases of the removed tests.
1 parent 995112f
alpha_services.ml
(*****************************************************************************)
(* *)
(* Open Source License *)
(* Copyright (c) 2018 Dynamic Ledger Solutions, Inc. <contact@tezos.com> *)
(* Copyright (c) 2019-2020 Nomadic Labs <contact@nomadic-labs.com> *)
(* *)
(* Permission is hereby granted, free of charge, to any person obtaining a *)
(* copy of this software and associated documentation files (the "Software"),*)
(* to deal in the Software without restriction, including without limitation *)
(* the rights to use, copy, modify, merge, publish, distribute, sublicense, *)
(* and/or sell copies of the Software, and to permit persons to whom the *)
(* Software is furnished to do so, subject to the following conditions: *)
(* *)
(* The above copyright notice and this permission notice shall be included *)
(* in all copies or substantial portions of the Software. *)
(* *)
(* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR*)
(* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, *)
(* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL *)
(* THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER*)
(* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING *)
(* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER *)
(* DEALINGS IN THE SOFTWARE. *)
(* *)
(*****************************************************************************)
open Alpha_context
let custom_root = RPC_path.open_root
module Seed = struct
module S = struct
open Data_encoding
let seed =
RPC_service.post_service
~description:"Seed of the cycle to which the block belongs."
~query:RPC_query.empty
~input:empty
~output:Seed.seed_encoding
RPC_path.(custom_root / "context" / "seed")
end
let () =
let open Services_registration in
register0 ~chunked:false S.seed (fun ctxt () () ->
let l = Level.current ctxt in
Seed.for_cycle ctxt l.cycle)
let get ctxt block = RPC_context.make_call0 S.seed ctxt block () ()
end
module Nonce = struct
type info = Revealed of Nonce.t | Missing of Nonce_hash.t | Forgotten
let info_encoding =
let open Data_encoding in
union
[
case
(Tag 0)
~title:"Revealed"
(obj1 (req "nonce" Nonce.encoding))
(function Revealed nonce -> Some nonce | _ -> None)
(fun nonce -> Revealed nonce);
case
(Tag 1)
~title:"Missing"
(obj1 (req "hash" Nonce_hash.encoding))
(function Missing nonce -> Some nonce | _ -> None)
(fun nonce -> Missing nonce);
case
(Tag 2)
~title:"Forgotten"
empty
(function Forgotten -> Some () | _ -> None)
(fun () -> Forgotten);
]
module S = struct
let get =
RPC_service.get_service
~description:"Info about the nonce of a previous block."
~query:RPC_query.empty
~output:info_encoding
RPC_path.(custom_root / "context" / "nonces" /: Raw_level.rpc_arg)
end
let register () =
let open Services_registration in
register1 ~chunked:false S.get (fun ctxt raw_level () () ->
let level = Level.from_raw ctxt raw_level in
Nonce.get ctxt level >|= function
| Ok (Revealed nonce) -> ok (Revealed nonce)
| Ok (Unrevealed {nonce_hash; _}) -> ok (Missing nonce_hash)
| Error _ -> ok Forgotten)
let get ctxt block level = RPC_context.make_call1 S.get ctxt block level () ()
end
type error += No_available_snapshots of {min_cycle : int32}
let () =
Error_monad.register_error_kind
`Permanent
~id:"no_available_snapshots"
~title:"No available snapshots"
~description:"No available snapshots"
~pp:(fun ppf min_cycle ->
Format.fprintf ppf "No available snapshots until cycle %ld" min_cycle)
Data_encoding.(obj1 (req "min_cycle" int32))
(function
| No_available_snapshots {min_cycle} -> Some min_cycle | _ -> None)
(fun min_cycle -> No_available_snapshots {min_cycle})
module Snapshot_index = struct
module S = struct
let cycle_query : Cycle.t option RPC_query.t =
let open RPC_query in
query (fun x -> x)
|+ opt_field "cycle" Cycle.rpc_arg (fun cycle -> cycle)
|> seal
let selected_snapshot =
RPC_service.get_service
~description:
"Returns the index of the selected snapshot for the current cycle or \
for the specific `cycle` passed as argument, if any."
~query:cycle_query
~output:Data_encoding.int31
RPC_path.(custom_root / "context" / "selected_snapshot")
end
let register () =
let open Services_registration in
register0 ~chunked:false S.selected_snapshot (fun ctxt cycle () ->
(* max_snapshot_index can be determined using constants only *)
let blocks_per_stake_snapshot =
Alpha_context.Constants.blocks_per_stake_snapshot ctxt
in
let blocks_per_cycle = Alpha_context.Constants.blocks_per_cycle ctxt in
let preserved_cycles =
Int32.of_int (Alpha_context.Constants.preserved_cycles ctxt)
in
let cycle =
match cycle with
| None -> Level.(current ctxt).cycle
| Some cycle -> cycle
in
if Compare.Int32.(Cycle.to_int32 cycle <= Int32.succ preserved_cycles)
then
(* Early cycles are corner cases, fail if requested *)
fail
(No_available_snapshots {min_cycle = Int32.add preserved_cycles 2l})
else
let max_snapshot_index =
Int32.div blocks_per_cycle blocks_per_stake_snapshot |> Int32.to_int
in
Alpha_context.Stake_distribution.compute_snapshot_index
ctxt
cycle
~max_snapshot_index)
let get ctxt block ?cycle () =
RPC_context.make_call0 S.selected_snapshot ctxt block cycle ()
end
module Contract = Contract_services
module Constants = Constants_services
module Delegate = Delegate_services
module Voting = Voting_services
module Sapling = Sapling_services
module Tx_rollup = Tx_rollup_services
module Liquidity_baking = struct
module S = struct
let get_cpmm_address =
RPC_service.get_service
~description:"Liquidity baking CPMM address"
~query:RPC_query.empty
~output:Alpha_context.Contract.encoding
RPC_path.(custom_root / "context" / "liquidity_baking" / "cpmm_address")
end
let register () =
let open Services_registration in
register0 ~chunked:false S.get_cpmm_address (fun ctxt () () ->
Alpha_context.Liquidity_baking.get_cpmm_address ctxt)
let get_cpmm_address ctxt block =
RPC_context.make_call0 S.get_cpmm_address ctxt block () ()
end
module Cache = struct
module S = struct
let cached_contracts =
RPC_service.get_service
~description:"Return the list of cached contracts"
~query:RPC_query.empty
~output:
Data_encoding.(list @@ tup2 Alpha_context.Contract.encoding int31)
RPC_path.(custom_root / "context" / "cache" / "contracts" / "all")
let contract_cache_size =
RPC_service.get_service
~description:"Return the size of the contract cache"
~query:RPC_query.empty
~output:Data_encoding.int31
RPC_path.(custom_root / "context" / "cache" / "contracts" / "size")
let contract_cache_size_limit =
RPC_service.get_service
~description:"Return the size limit of the contract cache"
~query:RPC_query.empty
~output:Data_encoding.int31
RPC_path.(
custom_root / "context" / "cache" / "contracts" / "size_limit")
let contract_rank =
RPC_service.post_service
~description:
"Return the number of cached contracts older than the provided \
contract"
~query:RPC_query.empty
~input:Alpha_context.Contract.encoding
~output:Data_encoding.(option int31)
RPC_path.(custom_root / "context" / "cache" / "contracts" / "rank")
end
let register () =
let open Services_registration in
register0 ~chunked:true S.cached_contracts (fun ctxt () () ->
Script_cache.entries ctxt |> Lwt.return) ;
register0 ~chunked:false S.contract_cache_size (fun ctxt () () ->
Script_cache.size ctxt |> return) ;
register0 ~chunked:false S.contract_cache_size_limit (fun ctxt () () ->
Script_cache.size_limit ctxt |> return) ;
register0 ~chunked:false S.contract_rank (fun ctxt () contract ->
Script_cache.contract_rank ctxt contract |> return)
let cached_contracts ctxt block =
RPC_context.make_call0 S.cached_contracts ctxt block () ()
let contract_cache_size ctxt block =
RPC_context.make_call0 S.contract_cache_size ctxt block () ()
let contract_cache_size_limit ctxt block =
RPC_context.make_call0 S.contract_cache_size_limit ctxt block () ()
let contract_rank ctxt block contract =
RPC_context.make_call0 S.contract_rank ctxt block () contract
end
let register () =
Contract.register () ;
Constants.register () ;
Delegate.register () ;
Nonce.register () ;
Snapshot_index.register () ;
Voting.register () ;
Sapling.register () ;
Liquidity_baking.register () ;
Cache.register () ;
Tx_rollup.register ()
![swh spinner](/static/img/swh-spinner.gif)
Computing file changes ...