Skip to main content
Revision 605bdf68df0f239ac2c74b752cc65b3e3bbe4275 authored by dependabot[bot] on 01 November 2024, 13:22:26 UTC, committed by GitHub on 01 November 2024, 13:22:26 UTC
Bump libopencm3 from `1f3abd4` to `201f5bc`
Bumps [libopencm3](https://github.com/libopencm3/libopencm3) from `1f3abd4` to `201f5bc`.
- [Commits](https://github.com/libopencm3/libopencm3/compare/1f3abd43763fa39d23e737602b6d0011a45c70b2...201f5bcfb3fa70ee34818152463e7139f24db377)

---
updated-dependencies:
- dependency-name: libopencm3
  dependency-type: direct:production
...

Signed-off-by: dependabot[bot] <support@github.com>
1 parent 3200c9e
Raw File Download
nucleo-l4r5zi-ramtest.ld
EXTERN(vector_table)
ENTRY(reset_handler)
MEMORY
{
 rom (rx) : ORIGIN = 0x08000000, LENGTH = 2048K
 ram (rwx) : ORIGIN = 0x20000000, LENGTH = 192K
 ram2 (rwx) : ORIGIN = 0x20030000, LENGTH = 64K
 ram3 (rwx) : ORIGIN = 0x20040000, LENGTH = 384K
}
SECTIONS
{
 .text : {
  *(.vectors)
  . = ALIGN(448);
  *(.text*)
  . = ALIGN(4);
  *(.rodata*)
  . = ALIGN(4);
 } >rom
 .preinit_array : {
  . = ALIGN(4);
  __preinit_array_start = .;
  KEEP (*(.preinit_array))
  __preinit_array_end = .;
 } >rom
 .init_array : {
  . = ALIGN(4);
  __init_array_start = .;
  KEEP (*(SORT(.init_array.*)))
  KEEP (*(.init_array))
  __init_array_end = .;
 } >rom
 .fini_array : {
  . = ALIGN(4);
  __fini_array_start = .;
  KEEP (*(.fini_array))
  KEEP (*(SORT(.fini_array.*)))
  __fini_array_end = .;
 } >rom
 .ARM.extab : {
  *(.ARM.extab*)
 } >rom
 .ARM.exidx : {
  __exidx_start = .;
  *(.ARM.exidx*)
  __exidx_end = .;
 } >rom
 . = ALIGN(4);
 _etext = .;
 .data : {
  _data = .;
  *(.data*)
  . = ALIGN(4);
  _edata = .;
 } >ram AT >rom
 _data_loadaddr = LOADADDR(.data);
 .bss : {
  *(.bss*)
  *(COMMON)
  . = ALIGN(4);
  _ebss = .;
 } >ram
 .ram1 : {
 *(.ram1*)
 . = ALIGN(4);
 } >ram
 end = .;
 .ram2 : {
 *(.ram2*)
 . = ALIGN(4);
 } >ram2
 .ram3 : {
  *(.ram3*)
  . = ALIGN(4);
 } >ram3
 /DISCARD/ : { *(.eh_frame) }
 . = ALIGN(4);
}
PROVIDE(_stack = ORIGIN(ram) + LENGTH(ram));
back to top