Skip to main content

Browse the archive

Revision 7c6e92ca9aaca36287f4624cd358ddc7850f811c authored by Roman Lebedev on 07 December 2021, 02:15:18 UTC, committed by Steven Johnson on 07 December 2021, 20:30:24 UTC 
`apps/linear_algebra/benchmarks/macros.h`: don't forget SSE guard (#6471)
 
This is breaking i386 build:
https://buildd.debian.org/status/fetch.php?pkg=halide&arch=i386&ver=13.0.1-3&stamp=1638786518&raw=0
1 parent fb39d7e
Raw File
WipeStandardFlags.cmake 
function(wipe_standard_flags REGEX)
    get_property(IS_MULTI_CONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
    if (IS_MULTI_CONFIG)
        set(CONFIGS_TO_EDIT ${CMAKE_CONFIGURATION_TYPES})
    else ()
        set(CONFIGS_TO_EDIT ${CMAKE_BUILD_TYPE})
    endif ()

    get_property(ENABLED_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
    foreach (CFG IN LISTS CONFIGS_TO_EDIT)
        string(TOUPPER ${CFG} CFG_UPPER)
        foreach (L IN LISTS ENABLED_LANGUAGES)
            set(VAR CMAKE_${L}_FLAGS_${CFG_UPPER})
            string(REGEX REPLACE "(^| )${REGEX}($| )" " " ${VAR} "${${VAR}}")
            set(${VAR} "${${VAR}}" PARENT_SCOPE)
        endforeach ()
    endforeach ()
endfunction()
back to top