Revision 929f7874bd2925220a1375868df93a45e83c086a authored by hudson@andromeda.local on 01 August 2010, 23:13:27 UTC, committed by hudson@andromeda.local on 01 August 2010, 23:13:27 UTC
1 parent 7d9d659
patch-bin
#!/usr/bin/perl
# Apply a patch to a binary image.
use warnings;
use strict;
use File::Slurp;
my $fail = 0;
my $pass = 0;
my $file = shift;
my $image = read_file( $file, {binmode => ':raw'} )
or die "$0: Unable to read $file: $!\n";
while(<>)
{
s/[\r\n]//g;
next if /^Comparing files/;
my ($offset,$from,$to) = m/
^
([0-9A-Fa-f]+):
\s+
([0-9A-Fa-f]+)
\s+
([0-9A-Fa-f]+)
$/x or warn "Unable to parse: '$_'\n" and next;
$offset = hex $offset;
$from = chr( hex $from );
$to = chr( hex $to );
if( substr( $image, $offset, 1) eq $from )
{
substr( $image, $offset, 1 ) = $to;
$pass++;
next;
}
printf STDERR "%08x: %02x != %02x!\n",
$offset,
ord( $from ),
ord( substr( $image, $offset, 1 ) ),
;
$fail++;
}
die "$0: $fail errors reported\n" if $fail;
warn "$0: $file: patched $pass bytes\n";
write_file( $file, $image );
__END__
![swh spinner](/static/img/swh-spinner.gif)
Computing file changes ...