https://github.com/Kitware/CMake
Revision 97917900d146acd55a7e453f477c52cd2e816eb3 authored by Brad King on 10 February 2017, 15:41:50 UTC, committed by Brad King on 10 February 2017, 15:43:29 UTC
The `default.css` static content is no longer placed in the qthelp `_static` directory. If it does not exist, skip over it and insert the content of `basic.css` directly into `cmake.css`.
1 parent 971384c
Tip revision: 97917900d146acd55a7e453f477c52cd2e816eb3 authored by Brad King on 10 February 2017, 15:41:50 UTC
Utilities/Sphinx: Port qthelp css workaround to Sphinx 1.4
Utilities/Sphinx: Port qthelp css workaround to Sphinx 1.4
Tip revision: 9791790
CMakeTestSwiftCompiler.cmake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.
if(CMAKE_Swift_COMPILER_FORCED)
# The compiler configuration was forced by the user.
# Assume the user has configured all compiler information.
set(CMAKE_Swift_COMPILER_WORKS TRUE)
return()
endif()
include(CMakeTestCompilerCommon)
# Remove any cached result from an older CMake version.
# We now store this in CMakeSwiftCompiler.cmake.
unset(CMAKE_Swift_COMPILER_WORKS CACHE)
# This file is used by EnableLanguage in cmGlobalGenerator to
# determine that that selected C++ compiler can actually compile
# and link the most basic of programs. If not, a fatal error
# is set and cmake stops processing commands and will not generate
# any makefiles or projects.
if(NOT CMAKE_Swift_COMPILER_WORKS)
PrintTestCompilerStatus("Swift" "")
file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/main.swift
"import Foundation\n"
"print(\"CMake\")\n")
try_compile(CMAKE_Swift_COMPILER_WORKS ${CMAKE_BINARY_DIR}
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/main.swift
OUTPUT_VARIABLE __CMAKE_Swift_COMPILER_OUTPUT)
# Move result from cache to normal variable.
set(CMAKE_Swift_COMPILER_WORKS ${CMAKE_Swift_COMPILER_WORKS})
unset(CMAKE_Swift_COMPILER_WORKS CACHE)
set(Swift_TEST_WAS_RUN 1)
endif()
if(NOT CMAKE_Swift_COMPILER_WORKS)
PrintTestCompilerStatus("Swift" " -- broken")
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
"Determining if the Swift compiler works failed with "
"the following output:\n${__CMAKE_Swift_COMPILER_OUTPUT}\n\n")
message(FATAL_ERROR "The Swift compiler \"${CMAKE_Swift_COMPILER}\" "
"is not able to compile a simple test program.\nIt fails "
"with the following output:\n ${__CMAKE_Swift_COMPILER_OUTPUT}\n\n"
"CMake will not be able to correctly generate this project.")
else()
if(Swift_TEST_WAS_RUN)
PrintTestCompilerStatus("Swift" " -- works")
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
"Determining if the Swift compiler works passed with "
"the following output:\n${__CMAKE_Swift_COMPILER_OUTPUT}\n\n")
endif()
endif()
unset(__CMAKE_Swift_COMPILER_OUTPUT)
Computing file changes ...