Skip to main content

Browse the archive

https://github.com/Kitware/CMake
10 April 2024, 19:27:19 UTC
Revision 97917900d146acd55a7e453f477c52cd2e816eb3 authored by Brad King on 10 February 2017, 15:41:50 UTC, committed by Brad King on 10 February 2017, 15:43:29 UTC 
Utilities/Sphinx: Port qthelp css workaround to Sphinx 1.4
 
The `default.css` static content is no longer placed in the qthelp
`_static` directory.  If it does not exist, skip over it and insert
the content of `basic.css` directly into `cmake.css`.
1 parent 971384c
Raw File
Tip revision: 97917900d146acd55a7e453f477c52cd2e816eb3 authored by Brad King on 10 February 2017, 15:41:50 UTC
Utilities/Sphinx: Port qthelp css workaround to Sphinx 1.4
Tip revision: 9791790
FindIcotool.cmake 
# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

#.rst:
# FindIcotool
# -----------
#
# Find icotool
#
# This module looks for icotool.  This module defines the following
# values:
#
# ::
#
#   ICOTOOL_EXECUTABLE: the full path to the icotool tool.
#   ICOTOOL_FOUND: True if icotool has been found.
#   ICOTOOL_VERSION_STRING: the version of icotool found.

find_program(ICOTOOL_EXECUTABLE
  icotool
)

if(ICOTOOL_EXECUTABLE)
  execute_process(
    COMMAND ${ICOTOOL_EXECUTABLE} --version
    OUTPUT_VARIABLE _icotool_version
    ERROR_QUIET
    OUTPUT_STRIP_TRAILING_WHITESPACE
  )
  if("${_icotool_version}" MATCHES "^icotool \\([^\\)]*\\) ([0-9\\.]+[^ \n]*)")
    set( ICOTOOL_VERSION_STRING
      "${CMAKE_MATCH_1}"
    )
  else()
    set( ICOTOOL_VERSION_STRING
      ""
    )
  endif()
  unset(_icotool_version)
endif()

include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
FIND_PACKAGE_HANDLE_STANDARD_ARGS(
  Icotool
  REQUIRED_VARS ICOTOOL_EXECUTABLE
  VERSION_VAR ICOTOOL_VERSION_STRING
)

mark_as_advanced(
  ICOTOOL_EXECUTABLE
)
back to top