Revision b3924aab0c05828f41f25011a376c7c214cbc4b8 authored by Ron Burkey on 06 December 2020, 22:08:22 UTC, committed by Ron Burkey on 06 December 2020, 22:08:22 UTC
as opposed to the default compiler (gcc); that's only to help verify, to the extent that I can without a Mac, that it will build on a Mac. I.e., it's not a harbinger of a gratuitous change from gcc to clang! Also, documented a little better the compile-time switches that have been provided to assist when the build environment is too complex to allow using the default gcc or g++.
1 parent f88be71
RADAR_LEADIN_ROUTINES.agc
### FILE="Main.annotation"
## Copyright: Public domain.
## Filename: RADAR_LEADIN_ROUTINES.agc
## Purpose: Part of the reconstructed source code for LMY99 Rev 0,
## otherwise known as Luminary Rev 99, the second release
## of the Apollo Guidance Computer (AGC) software for Apollo 11.
## It differs from LMY99 Rev 1 (the flown version) only in the
## placement of a single label. The corrections shown here have
## been verified to have the same bank checksums as AGC developer
## Allan Klumpp's copy of Luminary Rev 99, and so are believed
## to be accurate. This file is intended to be a faithful
## recreation, except that the code format has been changed to
## conform to the requirements of the yaYUL assembler rather than
## the original YUL assembler.
##
## Assembler: yaYUL
## Contact: Ron Burkey <info@sandroid.org>.
## Website: www.ibiblio.org/apollo.
## Pages: 490-491
## Mod history: 2009-05-17 RSB Adapted from the corresponding
## Luminary131 file, using page
## images from Luminary 1A.
## 2016-12-14 RSB Proofed text comments with octopus/ProoferComments
## and corrected the errors found.
## 2017-08-01 MAS Created from LMY99 Rev 1.
## This source code has been transcribed or otherwise adapted from
## digitized images of a hardcopy from the MIT Museum. The digitization
## was performed by Paul Fjeld, and arranged for by Deborah Douglas of
## the Museum. Many thanks to both. The images (with suitable reduction
## in storage size and consequent reduction in image quality as well) are
## available online at www.ibiblio.org/apollo. If for some reason you
## find that the images are illegible, contact me at info@sandroid.org
## about getting access to the (much) higher-quality images which Paul
## actually created.
##
## The code has been modified to match LMY99 Revision 0, otherwise
## known as Luminary Revision 99, the Apollo 11 software release preceeding
## the listing from which it was transcribed. It has been verified to
## contain the same bank checksums as AGC developer Allan Klumpp's listing
## of Luminary Revision 99 (for which we do not have scans).
##
## Notations on Allan Klumpp's listing read, in part:
##
## ASSEMBLE REVISION 099 OF AGC PROGRAM LUMINARY BY NASA 2021112-51
## Page 490
BANK 25
SETLOC RRLEADIN
BANK
EBANK= RSTACK
# RADAR SAMPLING LOOP.
COUNT* $$/RLEAD
RADSAMP CCS RSAMPDT # TIMES NORMAL ONCE-PER-SECOND SAMPLING.
TCF +2
TCF TASKOVER # +0 INSERTED MANUALLY TERMINATES TEST.
TC WAITLIST
EBANK= RSTACK
2CADR RADSAMP
CAF PRIO25
TC NOVAC
EBANK= RSTACK
2CADR DORSAMP
CAF BIT14 # FOR CYCLIC SAMPLING, RTSTDEX=
EXTEND # RTSTLOC/2 + RTSTBASE
MP RTSTLOC
AD RTSTBASE # 0 FOR RR, 2 FOR LR.
TS RTSTDEX
TCF TASKOVER
# DO THE ACTUAL RADAR SAMPLE.
DORSAMP TC VARADAR # SELECTS VARIABLE RADAR CHANNEL.
TC BANKCALL
CADR RADSTALL
INCR RFAILCNT # ADVANCE FAIL COUNTER BUT ACCEPT BAD DATA
DORSAMP2 INHINT
CA FLAGWRD5 # DON'T UPDATE RSTACK IF IN R77.
MASK R77FLBIT
CCS A
TCF +4
DXCH SAMPLSUM
INDEX RTSTLOC
DXCH RSTACK
CS RTSTLOC # CYCLE RTSTLOC.
AD RTSTMAX
EXTEND
## Page 491
BZF +3
CA RTSTLOC
AD TWO # STORAGE IS DP
TS RTSTLOC
TCF ENDOFJOB # CONTINUOUS SAMPLING AND 2N TRIES - GONE.
# VARIABLE RADAR DATA CALLER FOR ONE MEASUREMENT ONLY.
VARADAR CAF ONE # WILL BE SENT TO RADAR ROUTINE IN A BY
TS BUF2 # SWCALL.
INDEX RTSTDEX
CAF RDRLOCS
TCF SWCALL # NOT TOUCHING Q.
RDRLOCS CADR RRRANGE # = 0
CADR RRRDOT # = 1
CADR LRVELX # = 2
CADR LRVELY # = 3
CADR LRVELZ # = 4
CADR LRALT # = 5
![swh spinner](/static/img/swh-spinner.gif)
Computing file changes ...