Skip to main content

Browse the archive

Revision f0ec9c65a8d67e50a16745e62a336355ddf5d03e authored by Linus Torvalds on 17 June 2022, 14:58:39 UTC, committed by Linus Torvalds on 17 June 2022, 14:58:39 UTC 
Merge tag 'char-misc-5.19-rc3' of git://git.kernel.org/pub/scm/linux/kernel/git/gregkh/char-misc
 
Pull char/misc driver fixes from Greg KH:
 "Here are some small char/misc driver fixes for 5.19-rc3 that resolve
  some reported issues.

  They include:

   - mei driver fixes

   - comedi driver fix

   - rtsx build warning fix

   - fsl-mc-bus driver fix

  All of these have been in linux-next for a while with no reported
  issues"

* tag 'char-misc-5.19-rc3' of git://git.kernel.org/pub/scm/linux/kernel/git/gregkh/char-misc:
  eeprom: at25: Split reads into chunks and cap write size
  misc: atmel-ssc: Fix IRQ check in ssc_probe
  char: lp: remove redundant initialization of err
2 parent s 9afc441 + 0a35780
Raw File
check-blacklist-hashes.awk 
#!/usr/bin/awk -f
# SPDX-License-Identifier: GPL-2.0
#
# Copyright © 2020, Microsoft Corporation. All rights reserved.
#
# Author: Mickaël Salaün <mic@linux.microsoft.com>
#
# Check that a CONFIG_SYSTEM_BLACKLIST_HASH_LIST file contains a valid array of
# hash strings.  Such string must start with a prefix ("tbs" or "bin"), then a
# colon (":"), and finally an even number of hexadecimal lowercase characters
# (up to 128).

BEGIN {
	RS = ","
}
{
	if (!match($0, "^[ \t\n\r]*\"([^\"]*)\"[ \t\n\r]*$", part1)) {
		print "Not a string (item " NR "):", $0;
		exit 1;
	}
	if (!match(part1[1], "^(tbs|bin):(.*)$", part2)) {
		print "Unknown prefix (item " NR "):", part1[1];
		exit 1;
	}
	if (!match(part2[2], "^([0-9a-f]+)$", part3)) {
		print "Not a lowercase hexadecimal string (item " NR "):", part2[2];
		exit 1;
	}
	if (length(part3[1]) > 128) {
		print "Hash string too long (item " NR "):", part3[1];
		exit 1;
	}
	if (length(part3[1]) % 2 == 1) {
		print "Not an even number of hexadecimal characters (item " NR "):", part3[1];
		exit 1;
	}
}
back to top