Revision fc96cb0e70319855d9a675273ec7b61f910bf72b authored by Ron Burkey on 17 June 2020, 23:06:20 UTC, committed by Ron Burkey on 17 June 2020, 23:06:20 UTC
emulation of the PTC printer peripheral. Corrected some comment typos and other bugs I just happened to notice without detecting them as errors.
1 parent a38a94f
S-BAND_ANTENNA_FOR_CM.agc
### FILE="Main.annotation"
## Copyright: Public domain.
## Filename: S-BAND_ANTENNA_FOR_CM.agc
## Purpose: A section of Artemis revision 071.
## It is part of the reconstructed source code for the first
## release of the flight software for the Command Module's
## (CM) Apollo Guidance Computer (AGC) for Apollo 15 through
## 17. The code has been recreated from a copy of Artemis 072.
## It has been adapted such that the resulting bugger words
## exactly match those specified for Artemis 071 in NASA
## drawing 2021154-, which gives relatively high confidence
## that the reconstruction is correct.
## Reference: 940
## Assembler: yaYUL
## Contact: Ron Burkey <info@sandroid.org>.
## Website: www.ibiblio.org/apollo/index.html
## Mod history: 2019-08-14 MAS Created from Artemis 072.
## Page 940
SETLOC SBAND
BANK
COUNT* $$/R05
EBANK= EMSALT
SBANDANT TC INTPRET
RTB CALL
LOADTIME # PICKUP CURRENT TIME SCALED B-28
CDUTRIG # COMPUTE SINES AND COSINES OF CDU ANGLES
STCALL TDEC1 # ADVANCE INTEGRATION TO TIME IN TDEC1
CSMCONIC # USING CONIC INTEGRATION
SLOAD BHIZ # ORIGIN OF REFERENCE INERTIAL SYSTEM IS
X2 # EARTH = 0, MOON = 2
EISOI
VLOAD
RATT
STORE RCM # MOVE RATT TO PREVENT WIPEOUT
DLOAD CALL # MOON, PUSH ON
TAT # GET ORIGINAL TIME
LUNPOS # COMPUTE POSITION VECTOR OF MOON
VAD VCOMP # R= -(REM+RCM) = NEG. OF S/C POS. VEC
RCM
GOTO
EISOI +2
EISOI VLOAD VCOMP # EARTH, R= -RCM
RATT
SETPD MXV # RCS TO STABLE MEMBER- B-1X B-29X B+1
2D # 2D
REFSMMAT # STABLE MEMBER. B-1X B-29X B+1= B-29
VSL1 PDDL # 8D
HI6ZEROS
STOVL YAWANG # ZERO OUT YAWANG, SET UP FOR SMNB
RCM # TRANSFORMATION. SM COORD. SCALED B-29
CALL
*SMNB*
STORE R # SAVE NAV. BASE COORDINATES
UNIT PDVL # 14D
R
VPROJ VSL2 # COMPUTE PROJECTION OF VECTOR INTO CM
HIUNITZ # XY-PLANE, R-(R.UZ)UZ
BVSU BOV # CLEAR OVERFLOW INDICATOR IF SET
R
COVCNV
COVCNV UNIT BOV # TEST OVERFLOW FOR INDICATION OF NULL
NOADJUST # VECTOR
PUSH DOT # 20D
HIUNITX # COMPUTE YAW ANGLE = ACOS (URP.UX)
SL1 ACOS # REVOLUTIONS SCALED B0
PDVL DOT # 22D YAWANG
## Page 941
URP
HIUNITY # COMPUTE FOLLOWING- URP.UY
SL1 BPL # POSITIVE
NOADJUST # YES, 0- 180 DEGREES
DLOAD DSU # NO, 181-360 DEGREES 20D
DPPOSMAX # COMPUTE 2 PI MINUS YAW ANGLE
PUSH # 22D YAWANG
NOADJUST VLOAD DOT # COMPUTE PITCH ANGLE
UR # ACOS (UR.UZ) - PI/2
HIUNITZ
SL1 ACOS # REVOLUTIONS B0
DSU
HIDP1/4
STODL RHOSB
YAWANG
STORE GAMMASB # PATCH FOR CHECKOUT
EXIT
CAF PRIO5
TC PRIOCHNG
CA EXTVBACT # IS BIT 5 STILL ON
MASK BIT5
EXTEND
BZF ENDEXT # NO, WE HAVE BEEN ANSWERED
CAF V06N51 # DISPLAY ANGLES
TC BANKCALL
CADR GOMARKFR
TC B5OFF # TERMINATE
TC B5OFF
TC ENDOFJOB # RECYCLE
CAF BIT3 # IMMEDIATE RETURN
TC BLANKET # BLANK R3
CAF PRIO4
TC PRIOCHNG
CAF BIT1 # DELAY MINIMUM TIME TO ALLOW DISPLAY IN
TC BANKCALL
CADR DELAYJOB
TCF SBANDANT
V06N51 VN 0651
RCM EQUALS 2D
UR EQUALS 8D
URP EQUALS 14D
YAWANG EQUALS 20D
PITCHANG EQUALS 22D
R EQUALS RCM
SBANK= LOWSUPER
## Page 942
## This page contains only assembler-generated messages.
![swh spinner](/static/img/swh-spinner.gif)
Computing file changes ...