Skip to main content

Browse the archive

Revision fda9a94fe6061908e1d66c111f9030baa62cccf7 authored by Brad King on 14 September 2017, 11:19:33 UTC, committed by Kitware Robot on 14 September 2017, 11:19:40 UTC 
Merge topic 'autogen-target-depends-fix-3-9-2'
 
06c8a37e Merge branch 'backport-autogen-target-depends' into autogen-target-depends-fix-3-9-2
b494308d Autogen: Tests: Backport tests for _autogen target dependencies
d0f15817 Autogen: Backport autogen target dependency as file dependency fix

Acked-by: Kitware Robot <kwrobot@kitware.com>
Merge-request: !1257
2 parent s d6b49ee + 06c8a37
Raw File
TestCXXAcceptsFlag.cmake 
# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

#.rst:
# TestCXXAcceptsFlag
# ------------------
#
# Deprecated.  See :module:`CheckCXXCompilerFlag`.
#
# Check if the CXX compiler accepts a flag.
#
# .. code-block:: cmake
#
#  CHECK_CXX_ACCEPTS_FLAG(<flags> <variable>)
#
# ``<flags>``
#  the flags to try
# ``<variable>``
#  variable to store the result

macro(CHECK_CXX_ACCEPTS_FLAG FLAGS  VARIABLE)
  if(NOT DEFINED ${VARIABLE})
    message(STATUS "Checking to see if CXX compiler accepts flag ${FLAGS}")
    try_compile(${VARIABLE}
      ${CMAKE_BINARY_DIR}
      ${CMAKE_ROOT}/Modules/DummyCXXFile.cxx
      CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${FLAGS}
      OUTPUT_VARIABLE OUTPUT)
    if(${VARIABLE})
      message(STATUS "Checking to see if CXX compiler accepts flag ${FLAGS} - yes")
      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
        "Determining if the CXX compiler accepts the flag ${FLAGS} passed with "
        "the following output:\n${OUTPUT}\n\n")
    else()
      message(STATUS "Checking to see if CXX compiler accepts flag ${FLAGS} - no")
      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
        "Determining if the CXX compiler accepts the flag ${FLAGS} failed with "
        "the following output:\n${OUTPUT}\n\n")
    endif()
  endif()
endmacro()
back to top