AC_INIT([darktable], [0.4], [hanatos@gmail.com])
AM_INIT_AUTOMAKE([-Wall -Werror foreign dist-bzip2])
AC_PREREQ(2.63)
AC_CONFIG_MACRO_DIR([m4])
AC_CANONICAL_HOST
AC_PROG_CC
AC_PROG_CXX
IT_PROG_INTLTOOL([0.40])
ALL_LINGUAS="ru sv"
AM_GLIB_GNU_GETTEXT
AM_GLIB_DEFINE_LOCALEDIR(DARKTABLE_LOCALEDIR)
GETTEXT_PACKAGE=darktable
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [translation domain])

AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2

AX_CC_MAXOPT
AC_MSG_CHECKING([whether to enable debugging])
AC_ARG_ENABLE(debug,
	      AC_HELP_STRING([--enable-debug], [build debug executable]))
if test "$enable_debug" = "yes"; then
   CFLAGS="-Wall -O0 -g -D_DEBUG"
   AC_MSG_RESULT([yes])
else
   AC_MSG_RESULT([no])
fi
dnl ***  disabled because of strange libgomp.so crashes for gcc < 4.4: :(
AX_GCC_VERSION([4], [4], [0], try_openmp="yes", try_openmp="no")
AC_ARG_ENABLE(openmp,
	      AC_HELP_STRING([--enable-openmp], [use multiple threads with openmp]))
if test "$enable_openmp" = "no"; then
   try_openmp="no"
   AC_MSG_RESULT([no])
else
   AC_MSG_RESULT([yes])
fi
if test "$try_openmp" = "yes"; then
    AC_OPENMP
fi
AC_PROG_LIBTOOL
PKG_PROG_PKG_CONFIG([0.22])
AC_MSG_CHECKING([whether to use gegl for rendering])
AC_ARG_ENABLE(gegl,
	      AC_HELP_STRING([--enable-gegl], [use gegl for rendering (dont do this)]),
        [
          if test "$enable_gegl" = "yes"; then
             AC_DEFINE(HAVE_GEGL, 1, [whether to use gegl for rendering])
             AC_MSG_RESULT([yes])
             PKG_CHECK_MODULES(GEGL, gegl >= 0.0.22)
          else
             AC_MSG_RESULT([no])
          fi
        ],
        [
             AC_DEFINE(USE_GEGL_CURVE, 1, [whether to use gegl for rendering])
             AC_MSG_RESULT([only for curve])
             PKG_CHECK_MODULES(GEGL, gegl >= 0.0.22)
        ]
        )
PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.18)
PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.26)
PKG_CHECK_MODULES(CAIRO, [cairo])
PKG_CHECK_MODULES(GTHREAD, [gthread-2.0])
PKG_CHECK_MODULES(GLADE, [libglade-2.0])
PKG_CHECK_MODULES(SQLITE, [sqlite3])
PKG_CHECK_MODULES(EXIV2, exiv2 >= 0.18)
PKG_CHECK_MODULES(PNG, libpng12)
AC_ARG_ENABLE(lensfun,
	      AC_HELP_STRING([--enable-lensfun], [build the lens correction plugin]),
        [
          AC_MSG_CHECKING([whether build the lensfun plugin])
          if test "$enable_lensfun" = "yes"; then
             PKG_CHECK_MODULES(LENSFUN, lensfun >= 0.2.3)
             AC_DEFINE(HAVE_LENSFUN, 1, [whether build the lensfun plugin])
             AC_MSG_RESULT([yes])
          else
             AC_MSG_RESULT([no])
          fi
          AM_CONDITIONAL([HAVE_LENSFUN], [test "$enable_lensfun" = yes])
        ],
        [
          PKG_CHECK_MODULES(LENSFUN, lensfun >= 0.2.3)
          AC_DEFINE(HAVE_LENSFUN, 1, [whether build the lensfun plugin])
          AM_CONDITIONAL([HAVE_LENSFUN], [true])
        ]
        )
 
AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
   [JPEG_LIBS="-ljpeg"])
AC_SUBST(JPEG_LIBS)

dnl *** Check for LittleCMS ***
AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
   [AC_DEFINE(HAVE_LCMS, 1, [whether the LittleCMS development environment is available])
    LCMS_LIBS="-llcms"])
AC_SUBST(LCMS_LIBS)

dnl *** mac os troubles ***
case $host_os in
  *mingw* )
    win32=yes
    darwin=no
    ;;
  *darwin* )
    win32=no
    darwin=yes
    ;;
  * )
    win32=no
    darwin=no
    ;;
esac

dnl *** Check for the Apple Carbon framework (needed for GDK_WINDOWING_QUARTZ). 
CARBON_LIBS=
if test $darwin = yes; then
  carbon_ok=no
  AC_MSG_CHECKING([for Mac OS X Carbon support])
  AC_TRY_CPP([
  #include <Carbon/Carbon.h>
  #include <ApplicationServices/ApplicationServices.h>
  #include <CoreServices/CoreServices.h>
  ], carbon_ok=yes)
  AC_MSG_RESULT($carbon_ok)
  if test "x$carbon_ok" = "xyes"; then
    CARBON_LIBS="-framework Carbon -framework Cocoa"
  fi
fi
AC_SUBST(CARBON_LIBS)



AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([
    Makefile
    po/Makefile.in
    src/Makefile
    src/LibRaw/Makefile
    src/iop/Makefile
    src/views/Makefile
    src/libs/Makefile
    pixmaps/Makefile
    pixmaps/plugins/Makefile
    pixmaps/plugins/darkroom/Makefile
    ])
dnl    src/gegl-operations/Makefile
AC_OUTPUT